多指标合成多维决策交易系统 — 基于RSI、MACD、布林带、成交量及趋势的量化策略

/*backtest
start: 2024-11-07 00:00:00
end: 2025-02-26 00:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_CTP","currency":"FUTURES"}]
*/

//@version=6
strategy("3/5 Indicator Strategy with Table", overlay=true)

// —————— Input Parameters —————— //
rsiLength = input.int(18, "RSI Length", minval=1)
macdFast = input.int(12, "MACD Fast", minval=1)
macdSlow = input.int(26, "MACD Slow", minval=1)
macdSignal = input.int(9, "MACD Signal", minval=1)
bbLength = input.int(20, "BB Length", minval=1)
bbMult = input.float(2.5, "BB Multiplier", minval=0.1)

// —————— Indicator Calculations ——————
// Bollinger Bands
bbBasis = ta.sma(close, bbLength)
dev = bbMult * ta.stdev(close, bbLength)
upperBB = bbBasis + dev
lowerBB = bbBasis - dev

// MACD
[macdLine, signalLine, histLine] = ta.macd(close, macdFast, macdSlow, macdSignal)

// RSI
rsi = ta.rsi(close, rsiLength)

// —————— Indicator Conditions ——————
rsiBullish = rsi < 30
rsiBearish = rsi > 70

macdBullish = macdLine > signalLine
macdBearish = macdLine < signalLine

bbBullish = close > lowerBB and close < upperBB
bbBearish = close < lowerBB

volumeBullish = volume > ta.sma(volume, 20)
volumeBearish = volume < ta.sma(volume, 20)

priceTrendBullish = close > ta.sma(close, 50)
priceTrendBearish = close < ta.sma(close, 50)

// —————— Signal Logic ——————
bullishSignals = ( (rsiBullish ? 1 : 0) + (macdBullish ? 1 : 0) + (bbBullish ? 1 : 0) + (volumeBullish ? 1 : 0) + (priceTrendBullish ? 1 : 0))

bearishSignals = ( (rsiBearish ? 1 : 0) + (macdBearish ? 1 : 0) + (bbBearish ? 1 : 0) + (volumeBearish ? 1 : 0) + (priceTrendBearish ? 1 : 0))

longCondition = bullishSignals >= 3
shortCondition = bearishSignals >= 3

// —————— Status Table ——————
var table statusTable = table.new(position.top_right, 2, 6, border_width=1)
if barstate.islastconfirmedhistory
    // Clear previous data
    table.cell(statusTable, 0, 0, "Indicator", text_size=size.small, bgcolor=color.gray)
    table.cell(statusTable, 1, 0, "Status", text_size=size.small, bgcolor=color.gray)
    
    // RSI Status
    table.cell(statusTable, 0, 1, "RSI", text_size=size.small)
    table.cell(statusTable, 1, 1, rsiBullish ? "Bullish" : "Bearish", 
              text_color=rsiBullish ? color.green : color.red, text_size=size.small)
    
    // MACD Status
    table.cell(statusTable, 0, 2, "MACD", text_size=size.small)
    table.cell(statusTable, 1, 2, macdBullish ? "Bullish" : "Bearish", 
              text_color=macdBullish ? color.green : color.red, text_size=size.small)
    
    // Bollinger Bands Status
    table.cell(statusTable, 0, 3, "BBands", text_size=size.small)
    table.cell(statusTable, 1, 3, bbBullish ? "Bullish" : "Bearish", 
              text_color=bbBullish ? color.green : color.red, text_size=size.small)
    
    // Volume Status
    table.cell(statusTable, 0, 4, "Volume", text_size=size.small)
    table.cell(statusTable, 1, 4, volumeBullish ? "Bullish" : "Bearish", 
              text_color=volumeBullish ? color.green : color.red, text_size=size.small)
    
    // Trend Status
    table.cell(statusTable, 0, 5, "Trend", text_size=size.small)
    table.cell(statusTable, 1, 5, priceTrendBullish ? "Bullish" : "Bearish", 
              text_color=priceTrendBullish ? color.green : color.red, text_size=size.small)

// —————— Strategy Execution ——————
if longCondition
    strategy.entry("Long", strategy.long)

if shortCondition
    strategy.entry("Short", strategy.short)

// —————— Simplified Plots ——————
plot(bbBasis, "BB Basis", #2962FF)
plot(upperBB, "BB Upper", color.red)
plot(lowerBB, "BB Lower", color.green)
plot(ta.sma(close, 50), "50 SMA", color.orange)

// —————— Signal Markers ——————
plotshape(longCondition, "Buy", shape.labelup, location.belowbar, color=color.new(color.green, 0), text="BUY", textcolor=color.white)
plotshape(shortCondition, "Sell", shape.labeldown, location.abovebar, color=color.new(color.red, 0), text="SELL", textcolor=color.white)

• 多重均线追踪策略与动态仓位管理系统
• 高级自动交易策略：多指标动量和支撑阻力趋势分析系统
• SSL通道双阶梯利润策略（SSL Channel Dual-Tranche Profit Strategy）
• 多指标动量波浪交易策略
• 增强型十字星烛台趋势反转量化交易策略
• 多周期超级趋势百分比风控策略
• 高级趋势捕捉型均线交叉多指标确认交易策略
• 多维度自适应趋势追踪与风险管理策略
• 多指标加权智能交易策略
• 波动率过滤双均线交叉高夏普比策略
• 双均线波动率自适应交易策略与多级利润优化系统
• 指数移动均线烛台停止交易策略
• 双均线交叉与随机指标结合的自适应追踪止损策略